System "Inside Number"
{
  Take the last number, bet on its layout in this order
    Dozen for 2 times
    Line  for 3 times
    Corner for 3 times
    Split for 9 times
    Straight-up until a win (doubling bet every 35 spins)
    
    On win, reset and take the next last number, repeat above
}
Method "main"
Begin
    While Starting a New Session
    Begin
        Load Single Wheel
        Call "Initialize"
        Call "Input"
    End

    While on Each Spin
    Begin
        Add 1 to Record "Spin Counter" Data
        Add 1 to Record "Multiplier Counter" Data

        Call "Check for Loss"
        Call "Check for win"
        
        If Flag "Ready to Bet" is False
        Begin
            Copy Last Number to Record "Target Number" Layout
            
            If Record "Target Number" Layout not = Number 0
            Begin
                Set Flag "Ready to Bet" to True
            End
        End
        
        If Flag "Ready to Bet" is True
        Begin
            Call "Place Bets"
        End
    End
End

Method "Check for Loss"
Begin
    If Any Inside Bet has lost each time
    Or Any Outside Bet has lost each time
    Begin
        If Bankroll<= Record "Stop" Data
        Begin
            Display "You have reached your Loss target.  System will End"
            Stop Session
            Exit
        End
    End
End

Method "Check for win"
Begin
    If Any Inside Bet has won each time
    Or Any Outside Bet has won each time
    Begin
        If Record "Sessions" Data Not = 0
        Begin
            Subtract 1 from Record "Sessions" Data
            
            If Record "Sessions" Data <=0
            Begin
                Display "You have completed all sessions.  System will End"
                Stop Session
                Exit
            End
        End
        
        If Bankroll>= Record "Win" Data
        Begin
            Display "You have reached your Win goal.  System will End"
            Stop Session
            Exit
        End

        Call "Initialize"
        Exit
    End
End

Method "Place Bets"
Begin
    If  Record "Spin Counter" Data >=1
    And Record "Spin Counter" Data <=2
    Begin
        Put 100% of Record "bet amount" Data to Dozen nearest of Record "Target Number" Layout
    End

    If  Record "Spin Counter" Data >=3
    And Record "Spin Counter" Data <=5
    Begin
        Put 100% of Record "bet amount" Data to Line nearest of Record "Target Number" Layout
    End

    If  Record "Spin Counter" Data >=6
    And Record "Spin Counter" Data <=8
    Begin
        Put 100% of Record "bet amount" Data to Corner nearest of Record "Target Number" Layout
    End

    If  Record "Spin Counter" Data >=9
    And Record "Spin Counter" Data <=11
    Begin
        Put 100% of Record "bet amount" Data to Street nearest of Record "Target Number" Layout
    End

    If  Record "Spin Counter" Data >=12
    And Record "Spin Counter" Data <=17
    Begin
        Put 100% of Record "bet amount" Data to Split nearest of Record "Target Number" Layout
    End

    If  Record "Spin Counter" Data >=18
    Begin
        If Record "Multiplier Counter" Data >35
        Begin
            Put 0 on Record "Multiplier Counter" Data
            Multiply 2 to Record "bet amount" Data
        End

        Put 100% of Record "bet amount" Data to Record "Target Number" Layout
    End
End

Method "Initialize"
Begin
    Clear Record "Target Number" Layout
    Put 1 on Record "bet amount" Data
    Put 0 on Record "Spin Counter" Data
    Set Flag "Ready to Bet" to False
End

Method "Input"
Begin
    Put 1 on Record "Sessions" Data
    Put 10 on Record "Win" Data
    Put 50 on Record "Stop" Data
    Put 100% of Bankroll to Record "Bankroll" Data
    
    Group
    Begin
        Display "For Single Zero wheel"
        Input Data "Enter your starting Bankroll" to Record "Bankroll" Data
        Input Data "Enter your Win Profit units" to Record "Win" Data
        Input Data "Enter your Stop Loss units" to Record "Stop" Data
        Input Data "Enter how many sessions to play
                    0=unlimited" to Record "Sessions" Data
    End
    
    Put 100% of Record "Bankroll" Data to Bankroll
    Add 100% of Bankroll to Record "Win" Data

    //Setup the Stop Loss by taking Bankroll-Stop = Lowest Bankroll to keep
    Put 100% of Bankroll to Record "temp" Data
    Subtract 100% of Record "Stop" Data to Record "temp" Data
    Put 100% of Record "temp" Data to Record "Stop" Data
End